3D Engineering

...Лучшее из общего.

  • Увеличить размер шрифта
  • Размер шрифта по умолчанию
  • Уменьшить размер шрифта

Запустите 3D Studio

Next Limit S.L. Мягкое соударение

Здесь вы найдете очень простой туториал, который покажет, как имитировать удар небольшого камня о жидкость. Таким образом вы получите общие представления о том, как работает RealFlow в комбинации с 3D Studio MAX и насколько просто экспортировать/импортировать анимацию из MAX в RealFlow.

Начало работы.

1. Запустите 3D Studio MAX. ( Убедитесь, что файл RfPack.dlo находится в вашем каталоге ..\plugins.)

2. В MAX загрузите сцену Impact.max, которая прилагается к этому уроку.

3. Теперь мы экспортируем анимацию, содержащуюся в этой сцене в RealFlow. Что бы сделать это, откройте панель Utility и используйте SceneData Saver, эта утилита содержится в файле RfPack.dlo и используется для экспорта анимации из MAX в RealFlow и RealWave. Утилита экспортирует в файлы с расширением .SD ( Scene Data ).
Если вы не обнаружили ее в панели Utility, то нажмите кнопку more... и вы увидите список всех утилит заруженных в ваш 3D Studio MAX.

3. Использование этой утилиты чрезвачайно просто. Кликните на кнопку SceneData Saver и потом на кнопку Server Settings.
Теперь вы увидите список геометрических объектов в сцене; выберите оба ( Pool и Stone ). Нажмите в правом нижнем углу кнопку Set и экспортируйте вашу
сцену с кадра 0 по кадр 100 в любой файл на диске.

Импорт данных в RealFlow

1. Теперь, когда вы экспортировали сцену в файл SceneData (SD) вы можете загрузить анимацию в RealFlow ( используйте верхнюю желтую иконку с надписью SD ) и проверить все ли импортировалось правильно, нажав кнопку ACTION и увидеть падает ли камень в бассейн так же, как и в МАХ.

ЗАМЕЧАНИЕ. Анимация запускается только по нажатию кнопки ACTION, но если вы нажмете BUZZ ничего не произойдет. Это происходит потому, что BUZZ используется только для подготовки и настройки жидкости перед тем как анимированные объекты и счетчик кадров начнут движение.

Если RealFlow импортировал SceneData файл успешно, то верхняя управляющая панель будет выглядеть так.

Подготовка RealFlow сцены для имитации.

1. Теперь наполним бассейн жидкостью. Сначала, зайдите в панель Fluids и удостоверьтесь, что процесс имитации находится на кадре 0 и времени 0.0, если нет просто нажмите кнопку RESET. ( По нажатию этой кнопки система сбрасывается в кадр 0 и время 0.0 и готова к правильной имитации ).

Есть много способов наполнить бассейн жидкостью. Я выбрал square эмиттер ( этот путь немного медленный, но дает хорошие результаты и вы сможете увидеть, как бассейн наполняеся жидкостью в любой момент ).

2. Что бы создать эмиттер просто нажмите на кнопку Square в панели Fluid. Теперь вы видите желтый квадрат с желтой стрелкой, направленной вниз.
Это и есть квадратный эмиттер, готовый к выбросу частиц вниз.

3. Теперь надо установить параметры эмиттера для правдоподобной имитации. Заполним панель свойств
square эмиттера.

- Density 2000: Плотность. Чем больше плотность, тем больше частиц в единице объема, тем реалистичнее имитация, но медленнее вычисления.

- Viscosity 6: Вязкость. Что бы получить брызги, когда камень упадет в бассейн поставим вязкость поменьше.

- Randomness 0.1: Фактор случайности, что бы получить более реалистичную картину.

- Max. particles 3500: Это просто максимальное число частиц, которые мы используем в имитации ( для избежания переливания жидкости через бассейн ).

Размеры и координаты эмиттера:

- Center: 0 0 0.5

- Angles: 0 0 0

- Dim: 0.5 0.5

4. Все готово, но прежде чем нажать на BUZZ мы должны подготовить объекты и daemon'ы.

Подготовка объектов.

1.Мы хотим увидеть, что камень взаимодействует с жидкостью, которая содержится в бассейне. Так вот, что бы это произошло, надо сделать объекты камень (Stone) и бассейн (Pool) видимыми для жидкости (Fluid). Для этого нажмите кнопку Edit Scene Tree в верхней контрольной панели. Появится окно, где все показаны все взаимодействия элементов в RealFlow. Нажмите кнопку ALL TO ALL. Сейчас, если вы откроете "под-дерево" с именем Objects в общем "дереве" свойств вашего square эмиттера, то вы увидите оба объекта.
.

Подготовка Daemons

1. Так как мы хотим имитировать ситуацию, происходящую на поверхности Земли, то должны ввести в сцену гравитацию. Зайдите в панель Daemons и нажмите кнопку Gravity. В основном окне RealFlow появится красная стрелка направленная вниз. Если вы вернетесь в окно Edit Scene Tree и откроете "под-дерево" с именем Daemons, вы увидите Gravity daemon, который мы только что сотворили. ( RealFlow автоматически соединяет жидкость и daemon
когда в сцене только один эмиттер жидкости ).

Наполним бассейн...

1. Нажмите кнопку BUZZ чтобы бассейн начал наполнятся водой. ВНИМАНИЕ ! Не нажимайте кнопку ACTION, иначе камень начнет движение до того как в бассейне будет вода.
На PII 233 МГц этот процесс занял около семи минут реального времени, до того, как вода наполнила бассейн и ее поверхность успокоилась. В окне контроля времени имитации это равнозначно 8 секундам.

Итак, прошло семь минут и в основном окне RealFlow вы видите нечто, напоминающее эту картинку. В этот момент я рекомендую сохранить сцену, поскольку если вы по ошибке нажмете RESET, то все сбросится в ноль и вам придется заново наполнять бассейн.

Подготовка Меша ( Mesh )

1. Сейчас очень хочется нажать ACTION, но перед этим необходимо экcпортировать некоторые данные, что бы сделать возможным дальнейший рендер, после того как процесс имитации будет завершен, например, нам необходимо сохранить Mesh-двоичный файл, содержащий информацию о поверхности жидкости. Нажмите еще раз кнопку BUZZ, этим вы остановите процесс подготовки жидкости. Идите в панель Meshes и нажмите кнопку New Mesh, потом кнопку Select All, что бы выбрать все эмиттеры жидкости в сцене и наконец, кнопку Add to all meshes. Это скажет RealFlow, что вы хотите строить меш по всем жидкостям в сцене ( в нашем случае всего по одной, которую сделает square эмиттер ).

2. Нажмите кнопку Primitive properties и установите 100% в Blend factor и 20% в Radius factor.

3. Идите в Mesh Post-Process и нажмите флажок Sharp Mesh filter, что бы сделать поверхность более гладкой.

4. Идите в панель Files и укажите корректный каталог для сохранения последовательность двоичных файлов, которые вы получите в процессе имитации. Проверьте, что вы поставили правильный флажок напротив того пакета, с которым работаете ( 3D Studio MAX ).

Нажимаем ACTION

1. Вот теперь нажимаем кнопку ACTION и ждем несколько минут пока будет рассчитано наше соударение. В течение этого вы можете наблюдать, как маленький камень падает в жидкость и как деформируется меш поверхности на каждом кадре. Если все прошло без проблем, то вам только осьалось вернуться в MAX после завершения имитации и загрузить получившиюся последовательность mesh-файлов.

Назад в MAX

1. Теперь вы можете импортировать последовательность двоичных файлов для окончательного рендера. Идите в панель Create в MAX и нажмите кнопку RF Loader, укажите каталог, где лежат полученные mesh-файлы и префикс их имени. Нажмите кнопку Create Mesh для создания объекта в MAX'е.

2. Если все прошло нормально, то вы увидите поверхность жидкости в вьюпортах MAX и маленький камень упадет туда, создав немного брызг. Теперь используйте ваш талант что бы наложить подходящий материал и осветить сцену.d lighting into the scene for the final effect.

Это очень простой урок, иллюстрирующий базовые принципы работы RealFlow. Вы можете менять другие параметры и посмотреть на изменение поведения жидкости. Все что вам еще требуется - это время и практика....

Нажмите здесь для загрузки файла SceneData (IMPACT.SD) и сцены 3D Studio MAX (IMPACT.MAX)

 

Архив статей

 авг   Сентябрь 2019   окт

ВПВСЧПС
  1  2  3  4  5  6  7
  8  91011121314
15161718192021
22232425262728
2930 
Julianna Willis Technology

Случайная новость

Введение

Этот материал адресуется лицам, использующим или желающим использовать при работе с 3ds Max язык программирования MAXSript.
В параметрической модели имеется взаимосвязь параметров ее различных компонентов. В такой модели изменение значения одного параметра влечет изменения значений связанных с ним параметров модели. Подобные модели широко применяются в САПР. Примером такой модели в 3ds Max может служить объект Biped (двуногий).
3ds Max позволяет создавать параметрические модели посредством связывания параметров, употребления соответствующих контроллеров и модификаторов (преимущественно параметрических), а также за счет создания соответствующего MAXSript-кода, обеспечивающего пересчет модели при изменении значения управляющего параметра.
Рассмотрим параметрическую модель (рис. 1, а), в которой реализуются следующие зависимости:

R = abs(0.25 * H);

spherePosition = conePosition + [0, 0, 1.25 * H],

где
R – радиус сферы;
H – высота конуса;
spherePosition – позиция сферы (координаты ее центра);
conePosition – позиция конуса (координаты центра его основания).

а б

Рис. 1. Параметризованная модель: а – H = 50; б – H = -50

Рассматриваемую модель можно реализовать в 3ds Max несколькими способами. Приведем два из них. В первом употребим контроллеры Float Expression и Position Expression для формирования соответственно первой и второй зависимостей, а во втором – контроллеры Float Script и Position Script.
Создание модели и ее параметризацию средствами контроллеров Float Expression и Position Expression обеспечит следующий код:

delete $*
h = 50
cn = cone radius1:20 radius2:0 height:70 heightSegs:20 sides:24 wireColor:[6, 135, 113]
sph = sphere radius:(0.25 * cn.Height) segs:32 wireColor: [135, 110, 8]
sph.Pos = cn.Pos + [0, 0, 1.25 * cn.Height]
cn.Height.Controller = bezier_float()
fltX = float_expression()
fltX.AddScalarTarget "h" cn.Height.Controller
fltX.SetExpression "abs(0.25 * h)"
sph.Radius.Controller = fltX
--
pstnX = position_expression()
pstnX.AddScalarTarget "h" cn.Height.Controller
pstnX.AddVectorTarget "ps" cn.Position.Controller
pstnX.SetExpression "ps + [0, 0, 1.25 * h]"
sph.Position.Controller = pstnX
animate on (
at time 0f (cn.Height = h; cn.Pos = [0, 0, 0])
at time 50f (cn.Height = -h; cn.Pos = [0, 0, h])
at time 100f (cn.Height = h; cn.Pos = [0, 0, 0])
)
playAnimation()

Порядок действий следующий:

  1. Сцена очищается, и создаются объекты конус и сфера с именами cn и sph соответственно.
  2. После создания контроллера fltX (применяется конструктор float_expression) в контроллере создается скалярная переменная h, зависящая от высоты конуса (метод AddScalarTarget): значение переменной h будет равняться высоте конуса. Предварительно этому параметру (высоте конуса) назначается контроллер Bezier Float, ссылка на который используется в качестве второго параметра метода AddScalarTarget.
  3. Далее задается выражение (метод SetExpression), результат которого возвращает контроллер fltX.
  4. Параметру сферы Radius назначается контроллер fltX.

Теперь изменение высоты конуса, например на вкладке Modify после выбора конуса, приведет к изменению радиуса сферы.
Для управления позицией сферы используется контроллер Position Expression, программируемый в следующем порядке:

  1. После создания контроллера pstnX (применяется конструктор position_expression) в контроллере создаются скалярная переменная h, зависящая от высоты конуса (метод AddScalarTarget), и векторная переменная ps, зависящая от позиции конуса (метод AddVectorTarget). Как и в случае метода AddScalarTarget, вторым параметром метода AddVectorTarget также является ссылка на контроллер (cn.Position.Controller). Значение переменной ps после установления такой связи будет равно значению позиции конуса (величина типа Point3).
  2. Далее задается выражение (метод SetExpression), результат которого возвращает контроллер pstnX.
  3. Свойству сферы Position назначается контроллер pstnX.

Наличие такого контроллера обеспечит надлежащее перемещение сферы при изменении позиции конуса.
Для демонстрации результата в точках 0f, 50f и 100f временной шкалы создаются ключи анимации высоты и позиции конуса.
После запуска программы можно открыть диалог настройки контроллера, например Float Expression (рис. 2), выполнив следующие действия: выбрать примитив Sphere – меню Graph Editors – Track View – Curve Editor – ветвь Objects – Sphere01 – Sphere (Object) – Radius – двойной удар мышью.

Рис. 2. Диалог настройки контроллера Float Expression

Порядок запуска MAXScript-кода в 3ds Max описан ниже.
Вторая реализация рассматриваемой модели, основанная на контроллерах Float Script и Position Script, поддерживается следующим кодом:

delete $*
h = 50
cn = cone radius1:20 radius2:0 height:70 heightSegs:20 sides:24 wireColor:clr
sph = sphere radius:(0.25 * cn.Height) segs:32 wireColor:clr2
sph.Pos = cn.Pos + [0, 0, 1.25 * cn.Height]
fltS = float_script()
fltS.AddNode "cn2" cn
fltS.Script = "abs(0.25 * cn2.Height)"
sph.Radius.Controller = fltS
--
psS = position_script()
psS.AddNode "cn2" cn
psS.Script = "cn2.Pos + [0, 0, 1.25 * cn2.Height]"
sph.Position.Controller = psS
animate on (
at time 0f (cn.Height = h; cn.Pos = [0, 0, 0])
at time 50f (cn.Height = -h; cn.Pos = [0, 0, h])
at time 100f (cn.Height = h; cn.Pos = [0, 0, 0])
)
playAnimation()

В обоих контроллерах определяется переменная cn2 (метод AddNode), хранящая ссылку на объект конус. Это обеспечивает доступ к свойствам конуса, что и используется соответствующим образом в Script-выражениях контроллеров (свойство Script).
С другими возможностями программного управления моделями 3ds Max можно познакомиться, обратившись, например, к приведенным в конце урока источникам.
Рассмотренную модель можно, разумеется, реализовать интерактивно, без применения MAXScript. Следующая модель такой альтернативы не имеет.

Описание модели стула

В рассматриваемом примере регулируемым параметром является радиус скруглений R между отдельными компонентами модели стула. Изменение радиуса влечет изменение высоты ножек стула, размеров его сиденья и спинки (рис.3).

а б

Рис. 3. Параметризованный стул: а - R = 5; б - R = 15

Модель имеет следующие характеристики:

  1. Радиус всех скруглений одинаков и изменяется с шагом 1 в диапазоне 5 – 15 единиц.
  2. При пересчете модели сохраняются габариты стула, хранимые глобальными переменными wX, wY и wZ, а также размеры и положение задних ножек стула.
  3. Каркас стула воспроизводится цилиндрами и дугами (примитивы Cylinder и Arc); последние используются для отображения скруглений.
  4. Сиденье и списка стула отображаются посредством примитива Plane (плоскость).
  5. Сиденье отстоит от основания стула на 0.5 * wZ.

MAXScript-реализация модели стула

Параметризация модели выполняется средствами MAXScript. Код, обеспечивающий построение и управление моделью, а также создание и вывод управляющего диалога, имеет следующий вид:

global rlFlt
global clr = [6, 135, 113], clr2 = [135, 110, 8]
global wX = 60.0, wY = 45.0, wZ = 120.0
global arrC = #(), arrRc = #()
--
fn Prps = (
 delete $*
 units.DisplayType = #Generic
 units.SystemType = #Inches
 viewport.SetLayout #layout_4
 viewport.ActiveViewport = 4
 max vpt persp user
 viewport.SetGridVisibility 4 false
 max tool zoomExtents
 backgroundColor = color 200 200 200
)
--
fn fndPs R wX wY wZ &arrPs = (
 x = 0.5 * wX
 y = 0.5 * wY
 vY = [0, wY, 0]
 wZ2 = 0.5 * wZ
 p1 = [-x, -y, 0]; p2 = p1 + vY
 p3 = [x, -y, 0]; p4 = p3 + vY
 p5 = [0, -y, wZ2]; p6 = p5 + vY
 p7 = [x, -y, 0.75 * wZ]; p8 = p7 + vY
 p9 = [x + 2 * R, 0, wZ]
 p10 = [-x, -y, wZ2 - R]
 p11 = [x, -y, wZ2 + R]
 arrPs = #(p1, p2, p3, p4, p5, p6, p7, p8, p9, p10, p11)
 for k = 1 to 2 do arrC[k].Height = wZ2 - R
 for k = 5 to 6 do arrC[k].Height = wX - 2 * R
 for k = 7 to 8 do arrC[k].Height = wZ2 - 2 * R
 arrC[9].Height = wY - 2 * R
)
--
fn fndPs2 R wX wY wZ &arrPs2 = (
 x = 0.5 * wX
 y = 0.5 * wY
 vY = [0, wY, 0]
 wZ2 = wZ / 2
 pc1 = [-x + R, -y, wZ2 - R]; pc2 = pc1 + vY
 pc3 = [x - R, -y, wZ2 + R]; pc4 = pc3 + vY
 pc5 = [x + R, -y, wZ - R]; pc6 = pc5 + vY
 pc7 = [x + R, -y + R, wZ]; pc8 = pc7 + [0, wY - 2 * R, 0]
 arrPs2 = #(pc1, pc2, pc3, pc4, pc5, pc6, pc7, pc8)
)
--
fn mkChr R wX wY wZ = (
 Prps()
 arrC = for k = 1 to 11 collect cylinder wireColor:clr2 radius:2
 arrPs = #()
 arrPs2 = #()
 fndPs R wX wY wZ &arrPs
 fndPs2 R wX wY wZ &arrPs2
 arrC[3].Height = arrC[4].Height = sqrt ((0.5 * wX)^2 + (0.5 * wZ)^2)
 for k = 10 to 11 do arrC[k].Height = wY
 for k = 5 to 9 do arrC[k].Pivot = [0, 0, 0.5 * arrC[k].Height]
 for k = 1 to 11 do arrC[k].Pos = arrPs[k]
 for k = 3 to 4 do rotate arrC[k] -(atan (1.0 * wX / wZ)) [0, 1, 0]
 for k = 5 to 6 do rotate arrC[k] 90 [0, 1, 0]
 for k = 9 to 11 do rotate arrC[k] -90 [1, 0, 0]
 rc = arc radius:R from:0 to:90 pie:off reverse:off pos:[0, 0, 0] \
  rotation:(quat -0.5 0.5 -0.5 -0.5) wireColor:clr2 \
  render_renderable:on render_displayRenderMesh:on render_useViewportSettings:off \
  render_mapcoords:on render_displayRenderSettings:off render_viewport_thickness:4.0 \
  render_thickness:4.0
 arrRc = for k = 1 to 7 collect copy rc
 arrRc.WireColor = clr2
 arrRc[6].Rotation = quat 0 0 -0.707107 0.707107
 arrRc[7].Rotation = quat 0 0 0 1
 insertItem rc arrRc 1
 arrNg = #(0, 0, 180, 180, 0, 0, 0, 0)
 for k = 1 to 8 do (
  rotate arrRc[k] arrNg[k] [0, 1, 0]
  arrRc[k].Pos = arrPs2[k]
 )
 max tool zoomExtents
 global pln = plane length:wY width:(wX - R) lengthSegs:1 widthSegs:1 \
  pos:[0, 0, wZ / 2] wireColor:clr
 p = arrPs[7]; p[2] = 0
 global pln2 = plane length:wY width:(wZ / 2 - 2 * R) lengthSegs:1 widthSegs:1 \
  pos:p wireColor:clr
 rotate pln2 -90 [0, 1, 0]
)
--
fn chgChr R wX wY wZ = (
 for k = 1 to 2 do arrC[k].Height = 0.5 * wZ - R
 for k = 5 to 6 do arrC[k].Scale = [1, 1, (wX - 2 * R) / arrC[5].Height]
 for k = 7 to 8 do arrC[k].Scale = [1, 1, (0.5 * wZ - 2 * R) / arrC[7].Height]
 arrC[9].Scale = [1, 1, (wY - 2 * R) / arrC[9].Height]
 arrC[9].Pos = [0.5 * wX + 2 * R, 0, wZ]
 arrC[10].Pos = [-0.5 * wX, -0.5 * wY, 0.5 * wZ - R]
 arrC[11].Pos = [0.5 * wX, -0.5 * wY, 0.5 * wZ + R]
 arrPs2 = #()
 fndPs2 R wX wY wZ &arrPs2
 for k = 1 to 8 do arrRc[k].Pos = arrPs2[k]
 arrRc.Radius = R
 pln.Width = wX - 2 * R
 pln2.Width = 0.5 * wZ - 2 * R
)
--
rollout rChr "Chair" width:120 height:100 (
 spinner spnR "R " pos:[15,5] width:100 height:20 range:[5,15,1] type:#integer
 colorPicker theClr "Color " pos:[15,30] width:100 height:20 color:clr modal:true
 button btnNmt "Animation" pos:[15,55] width:100 height:20 toolTip:"Play animation"
 button btnCls "Close" pos:[15,80] width:100 height:20 toolTip:"Close Dialog"
 on spnR changed val do chgChr val wX wY wZ
 on theClr changed newClr do (
  clr = newClr
  pln.WireColor = newClr
  pln2.WireColor = newClr
 )
 on btnNmt pressed do (
  animationRange = interval 0f 100f
  timeConfiguration.PlaybackLoop = false
  with redraw off (
   animate on (
    at time 0f chgChr spnR.Range[1] wX wY wZ
    at time 50f chgChr spnR.Range[2] wX wY wZ
    at time 100f chgChr 10 wX wY wZ
   )
  )
  max tool zoomExtents
  playAnimation()
  with redraw off (
   sliderTime = 0f
   chgChr 10 wX wY wZ
  )
  spnR.Value = 10
 )
 on btnCls pressed do closeRolloutFloater rlFlt
)
--
function opnRlFlt = (
 if rlFlt != undefined then closeRolloutFloater rlFlt
 rlFlt = newRolloutFloater "Chair" (rChr.Width + 35) (rChr.Height + 35) 50 50
 addRollout rChr rlFlt rolledUp:false
 rChr.spnR.Value = 10
)
--
mkChr 10 wX wY wZ
opnRlFlt()

Запуск программы

Запуск программы выполняется в 3ds Max в следующем порядке:

  1. Открыть редактор кода (меню MAXScript – MAXScript Editor).
  2. Перейти в открывшийся диалог и при необходимости создать новую вкладку (Ctrl + N).
  3. Скопировать код, приведенный в уроке, в чистую вкладку редактора.
  4. Позиционироваться в любом месте скопированного кода и нажать Ctrl + E, либо воспользоваться меню редактора Tools – Evaluate All.
  5. Употребить появившийся диалог (рис. 4) для управления моделью стула, которая отобразится в сцене непосредственно перед открытием диалога.

Рис. 4. Управляющий диалог Chair

Описание программы

Построение стула обеспечивает функция mkChr, которая принимает в качестве параметров значения радиуса скруглений, длину, ширину и высоту стула – это соответственно параметры R, wX, wY и wZ. Стул состоит из 11 цилиндров (примитив Cylinder), 8 дуг (примитив Arc) и двух плоскостей (примитив Plane). Последние употребляются для отображения сиденья и спинки стула.
Переменные wX, wY и wZ объявлены как глобальные, что позволяет применять их в обработчике on btnNmt pressed управляющего диалога Chair (идентификатор rChr).
Цилиндры хранит массив arrC; номера цилиндров, то есть их индексы в массиве arrC, показаны на рис 5, а.

а б

Рис. 5. Нумерация компонентов модели стула: а – нумерация цилиндров; б – нумерация дуг

Дуги хранятся в массиве arrRc; их индексы в этом массиве показаны на рис. 5, б.
Плоскости для сиденья и спинки имеют в программе соответственно идентификаторы pln и pln2. Эти имена являются глобальными и поэтому доступны в обработчиках диалога Chair.
Перед построением модели функцией Prps удаляются все элементы сцены и устанавливаются требуемые параметры сеанса – это тип единиц измерения, число видовых портов (4), активный видовой порт (4) и его тип (Perspective). Кроме того, в этом видовом порте устраняется изображение сетки и выполняется команда max tool zoomExtents.
Координаты базовых точек цилиндров и дуг вычисляются соответственно функциями fndPs и fndPs2, принимающими вдобавок к параметрам R, wX, wY и wZ соответственно массивы arrPs и arrPs2. В эти массивы названные функции записывают необходимые для построения примитивов координаты их базовых точек. Нумерация базовых точек отвечает показанным на рис. 5 нумерациям цилиндров и дуг.
Параметризация модели обеспечивается функцией chgChr, которая вызывается обработчиком on spnR changed при изменении счетчика R (spinner spnR) диалога Chair. Также эта функция применяется при создании ключей анимации (кнопка Animation диалога Chair).
Функция принимает параметры R, wX, wY и wZ. Параметр R является изменяемым, и его значение берется равным показанию счетчика R диалога. Прочие параметры после запуска программы не изменяются.
Получив новое значение радиуса, функция chgChr:

  • изменяет высоту цилиндров 1 и 2 (свойство Height цилиндра);
  • соответствующим образом масштабирует цилиндры 5 – 9 (свойство Scale цилиндра);
  • изменяет положение цилиндров 9, 10 и 11 (свойство Pos цилиндра), смещая позицию цилиндров 10 и 11 в начало, а цилиндр 9 в конец соответствующих дуг модели;
  • изменяет координаты центра каждой дуги (свойство Pos дуги); для этой цели, как и при создании модели, выполняется обращение к функции fndPs2;
  • изменяет значение радиуса каждой дуги (свойство Radius дуги);
  • модифицирует ширину сиденья и спинки (свойство Width плоскостей pln и pln2).

В рассматриваемой модели масштабирование цилиндра будет вызывать надлежащий эффект, если базовая точка цилиндра (свойство Pivot) расположена в его центре, а не в центре основания, как это предусмотрено по умолчанию. Эта проблема решается при создании модели функцией mkChr за счет употребления следующего кода:

for k = 5 to 9 do arrC[k].Pivot = [0, 0, 0.5 * arrC[k].Height]

Таким образом, функция chgChr обеспечивает получение экземпляра модели, отвечающего принятому функцией значению радиуса скругления R. Все преобразования выполняются исходя из неизменности габаритов стула и положения его сиденья. Единственными неизменяемыми компонентами модели являются цилиндры 3 и 4, отображающие задние ножки стула.
Кроме обработчика on spnR changed, вызываемого при изменении показания счетчика R, диалог Chair (см. рис. 4) содержит обработчики on theClr changed, on btnNmt pressed и on btnCls pressed do, выполняемые соответственно при нажатии на полосу с цветом (элемент colorPicker), на кнопку Animation (элемент button btnNmt) и Close (элемент button btnCls).
Ключи анимации рассчитываются в точках 0f, 50f и 100f временной шкалы после нажатия на кнопку Animation диалога Chair: выполняется обработчик on btnCls pressed do, в котором трижды вызывается функция chgChr. После воспроизведения анимации (метод playAnimation) временная шкала устанавливается в точку 0f и вновь вызывается функция chgChr со значением параметра R, равным 10. Это обеспечивает появление начального образа стула. Это же значение радиуса скругления устанавливается и в счетчике R диалога (spnR.Value = 10).

Заключение

Параметрические модели требуют дополнительных издержек при их создании. Поэтому вопрос о целесообразности параметризации модели решается с учетом предполагаемых выгод.
Издержки связаны с необходимостью:

  • структуризации модели и сохранения в ней параметров, влияющих на ее геометрию;
  • поиска зависимостей между параметрами;
  • реализации этих зависимостей (как правило, с привлечением MAXScript).

Основной эффект параметризации – это возможность получения модифицированного экземпляра модели, за счет изменения небольшого числа параметров. Так, параметрическая модель кузова автомобиля может обеспечить пересчет всех компонентов кузова при изменении геометрии двери или иной части кузова.
Также параметрические модели несложно снабдить надлежащим, более удобным пользовательским интерфейсом, обеспечивающим управление отдельными параметрами модели и, значит, моделью в целом.
Кроме того, параметризация предоставляет дополнительные возможности для анимации модели, что, в частности, существенно при создании мультимедийных приложений.

Источники

  1. Autodesk® 3ds Max® 2009 MAXScript Reference.
  2. Бартеньев О. В. Программирование модификаторов 3ds Max. Учебно-справочное пособие. – М.:Физматкнига, 2009. – 341 с.
  3. http://100byte.ru/

далее